表紙カバーを裁断せずに「切り取る」ためのMacro - その漫画自炊オタクはImageJマクロに恋をする

f:id:yu3xx:20200624024125j:plain

表紙カバーの処理、みなさんはどうしてますか？

表紙カバーも裁断して、CDで言うところのジャケットにあたる大事なオモテの部分だけ一番最初にドンと表示させるのが私は好きです。

でも、カバーを裁断するのって結構面倒だし、そのあとバラバラ細かいパーツがかさばって、たとえ一時的にでも保管するのが大変だと思うんですよね。

そこで今回ご紹介するのは、

表紙カバーを切らずにまるまんま長尺でスキャンしたものを、ImageJの画像処理で「トリミング」する方法です。

切り取り方法

f:id:yu3xx:20200102230529p:plain — Rectangle Toolを選択し、ROIを設定

まずRectangle Toolを使用して切り取りたい箇所にROI（Region of Interest：ロイ）を設定します。

その後、ImageJ上部タブから[Image]→[Crop]とするだけで「切り取る」ことが出来ます。

これだけです。 物理的に「裁断」するよりずっと簡単ですよね？

ただ、1枚だけだったらこれでもう十分なのですが、例えば100巻分これをやるとなると、いくらCropするだけだとしても気が滅入りますよね？

そこで次は、フォルダにぶち込んだ全ての表紙カバーデータを、まとめて一気にCropするマクロを紹介します。

Macroで一括自動Crop

指定したフォルダ内の全ての画像に対し、1枚目は手動でROIを設定し、2枚目以降はそのROI位置を用いて「切り取る」ためのマクロです。

//Crop_Using_ROI.txt

//Folder setting
showMessage("Select Open Folder");
openDir = getDirectory("Choose a Directory");
showMessage("Select Save Folder");
saveDir = getDirectory("Choose a Directory");
list = getFileList(openDir);

//Clear ROI Manager
roiCount=roiManager("count");
if(roiCount>0){
	roiManager("Deselect");
	roiManager("Delete");
}

//Operation
for (i=0; i<list.length;i++){
	operation();
}

roiManager("Deselect");
roiManager("Delete");
print("Crop",list.length,"images");
print("oshimai");

//Difine function
function operation(){

	open(openDir+list[i]);
	
	name = getTitle;
	dotIndex = lastIndexOf(name, ".");
	title = substring(name, 0, dotIndex);

	if(i==0){
		setTool("rectangle");
		waitForUser("ROI selection","Set ROI using rectangle tool, then click \"OK\".");
		roiManager("Add");
	}else{
		roiManager("Select", 0);
	}
	run("Crop");

	newname = title+".jpg";
	rename(newname);
	saveAs("Jpeg", saveDir+newname);
	close(newname);
}

表紙カバーのサイズは巻によってそこまで大きく変化しないため、1枚目のROI位置で全画像Cropしても、大きな問題はないと思います。

準備としては、「表紙データ」のみを一つのフォルダに集めておくだけでOKです。