【ImageJマクロ超入門】#8　二次元画像のピクセル値を取得する方法 - その漫画自炊オタクはImageJマクロに恋をする


//example 8-1

//あらかじめ画像を開いておく


//画像をグレースケール8bitに置き換え
run("8-bit");

//画像のタテとヨコのpixel数を取得
w = getWidth();
h = getHeight();

//座標xとyで二重ループ
for(x=0; x<w; x++){
	for(y=0; y<h; y++){
		//オリジナルのpixel値取得
		originalValue = getPixel(x, y);
	
		//Max値255からオリジナルpixel値を引く
		newValue = 255 - originalValue;
		
		//新しいpixel値で置き換え
		setPixel(x, y, newValue);
	}
}

二次元画像の解析では、xとyを二重でループさせることで全画素に対して順次処理を行います。

これが今回のポイントの一つです。

基本的にはxとyのどちらを先に書いてもOKですが、どちらを先に書くかで「画素チェックの走査方向」が変わります。

これを意識しておくことは、複雑な処理・解析をするときに重要となってきます。

サンプルコードではx固定で先にyループを回し、その後xを1つ大きくしてまたyループを回し...となるので、下図のような走査方向になります。

f:id:yu3xx:20210515011227j:plain

8bitグレースケールは256階調、最小値0、最大値255なので、255からオリジナルの値を引き算することで白黒反転できます。

f:id:yu3xx:20210515010938j:plain

白黒反転するとこうなるはずです。

自作関数による画像解析

二次元画像の扱い方がわかったところで、自作関数（ユーザー定義関数）を使って簡単な画像解析をしてみます。

自作関数の基礎解説は以下のリンクから。

今回は「ある値よりも大きなピクセル値を持つ画素の数をカウントする」という解析をしてみます。

サンプル2(条件を満たす画素のカウント)

閾値（threshold）とするピクセル値を、変数thとして設定。


//example 8-2

//あらかじめ画像を開いておく

run("8-bit");

a = countPixel(10);
print(a);

a = countPixel(128);
print(a);

a = countPixel(200);
print(a);


//-----------------------------------------------------------------------------

function countPixel(th){
	w = getWidth();
	h = getHeight();
	
	//countを初期化
	count = 0;

	for(y=0; y<h; y++){
		for(x=0; x<w; x++){
			pixelValue = getPixel(x, y);

			//閾値thよりも大きなpixel値のときだけカウントアップ
			if(pixelValue > th){
				count++;
			}
		}
	}
	return count;
}

//-----------------------------------------------------------------------------

実行すると、値が10以上の画素数、値が128以上の画素数、値が200以上の画素数が表示されます。

f:id:yu3xx:20210515012506p:plain
これが画素カウントを数える命令のテンプレです。